xsize=10
ysize=13
size xsize ysize
pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
tt=4*pt   !tick length
lw=0.5*pt !line width
glw=2*lw  !graph line width
ms=4*pt   !marker size

! graph settings
xmn=0
xmx=100
ymn=0
ymx=0.03
xticks=20
xsubticks=10
yticks=0.01
ysubticks=0.005

set lwidth lw
set hei fs
set just tl

! funky LaTeX commands
begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
end texpreamble

! set the normal font to AvantGarde-Demi, which is really obviously
! different to Palatino, so you can spot it if you forget to wrap
! text in \tex{}
set font psagd 

glw=2*lw
xgraphsize=11
ygraphsize=7
ygraphmove=6.3
yoffset=0.3

amove 0 ygraphmove*1+yoffset
begin graph
 size xgraphsize ygraphsize
 nobox
 
 data "mno-c2-interstitial-unit.tsv" d1=c1,c2
 
 xtitle "\tex{$\nu / \mu$ ($\si{\MHz}/\mu _{\mathrm{B}}$)}"
 xaxis min xmn max xmx dticks xticks dsubticks xsubticks
 xaxis format "round 1 prepend \tex{$ append $}"
 xticks length tt
 
 ytitle "\tex{$f(\nu /\mu )$ ($\mu _{\mathrm{B}}\cdot\si{\per\MHz}$)}"
 yaxis min ymn max ymx dticks yticks dsubticks ysubticks
 yaxis format "round 1 prepend \tex{$ append $}"
 yticks length tt

 d1 lstyle 3 color rgb255(156,122,199) lwidth glw
end graph

begin key
 nobox
 pos tl
 text "\tex{(a)}"
end key

xmn=0
xmx=11
ymn=0
ymx=0.3
xticks=2
xsubticks=1
yticks=0.1
ysubticks=0.05

amove 0 yoffset
begin graph
 size xgraphsize ygraphsize
 nobox
 
 data "mno-moment-pdf.tsv" d1=c1,c2
 
 xtitle "\tex{$\mu$ ($\mu _{\mathrm{B}}$)}"
 xaxis min xmn max xmx dticks xticks dsubticks xsubticks
 xaxis format "round 1 prepend \tex{$ append $}"
 xticks length tt
 
 ytitle "\tex{$g(\mu | \nu)$ ($\mu _{\mathrm{B}}^{-1}$)}"
 yaxis min ymn max ymx dticks yticks dsubticks ysubticks
 yaxis format "round 1 prepend \tex{$ append $}" nolast
 yticks length tt

 d1 lstyle 1 color rgb255(156,122,199) lwidth glw
 
 let d10=2 from 5.55 to 5.75
 fill x1,d10 color rgb255(200,240,168)
end graph

begin key
 nobox
 pos tl
 text "\tex{(b)}"
end key

amove 5.5 2
rotate 90
tex "$5.65\mu _{\mathrm{B}}$"