xsize=10
ysize=8
size xsize ysize

pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
tt=4*pt   !tick length
lw=0.5*pt !line width
glw=2*lw  !graph line width
ms=4*pt   !marker size

! graph settings
xmn=0
xmx=3
xticks=1
xsubticks=0.5
ymn=0
ymx=1.2
yticks=0.2
ysubticks=0.1

set lwidth lw
set hei fs
set just tl

! funky LaTeX commands
begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
end texpreamble

! set the normal font to AvantGarde-Demi, which is really obviously
! different to Palatino, so you can spot it if you forget to wrap
! text in \tex{}
set font psagd 

amove 0 0
begin graph
 size xsize ysize
 scale auto
 nobox
 
 xtitle "\tex{$x$}"
 xaxis min xmn max xmx dticks xticks dsubticks xsubticks
 xaxis format "fix 0 prepend \tex{$ append $}"
 xticks length tt
 
 ytitle "\tex{$\mathrm{erfc}(x)$}"
 yaxis min ymn max ymx dticks yticks dsubticks ysubticks
 yaxis format "fix 1 prepend \tex{$ append $}"
 yticks length tt

 data erfc.tsv d1=c1,c2
 
 d1 lstyle 1 lwidth glw color rgb255(48,80,248)
end graph