xsize=10
ysize=6
size xsize ysize
pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
tt=4*pt   !tick length
lw=0.5*pt !line width
glw=2*lw  !graph line width
ms=4*pt   !marker size

! graph settings
xmn=0
xmx=5
xticks=1
xsubticks=0.5
ymn=18000
ymx=26000
yticks=2000
ysubticks=1000
Aterrw=0.001

! funky LaTeX commands
begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
end texpreamble

set lwidth lw
set hei fs
set texscale scale
set just tl

xgraphsize=12.5
ygraphsize=7

amove -1 0
begin graph
 size xgraphsize ygraphsize
 nobox
 
 data "5K_100G_MP156.dat" d1=c1,c2 d2=c1,c3 d3=c1,c4
 data "18K_100G_MP156.dat" d4=c1,c2 d5=c1,c3 d6=c1,c4
 
 xtitle "\tex{$t$ (\si{\us})}"
 xaxis min xmn max xmx dticks xticks dsubticks xsubticks
 xaxis format "round 1 prepend \tex{$ append $}"
 xticks length tt
 
 ytitle "\tex{$A(t)$ (arb.)}"
 yaxis min ymn max ymx dticks yticks dsubticks ysubticks
 !yaxis format "round 5 prepend \tex{$ append $}"
 ylabels off
 yticks length tt
 
 d1 err d2 errwidth Aterrw lwidth lw color rgb(0,0.1,0.25)
 d4 err d5 errwidth Aterrw lwidth lw color rgb(0.25,0,0)

end graph

begin graph
 size xgraphsize ygraphsize
 nobox
 
 data "5K_100G_MP156.dat" d2=c1,c4
 data "18K_100G_MP156.dat" d1=c1,c4
 
 xaxis min xmn max xmx
 xaxis off
 
 yaxis min ymn max ymx
 yaxis off
 
 d2 smooth lstyle 1 lwidth glw color rgb255(48,80,248)
 d1 smooth lstyle 1 lwidth glw color rgb(1,0.05098,0.05098)
end graph

set color rgb(1,0.05098,0.05098)
amove 4.4 5.7
tex "$T=\SI{18}{\kelvin}$"
set color rgb255(48,80,248)
amove 7 1.7
tex "$T=\SI{5}{\kelvin}$"
