xsize=15.7
ysize=4.7
size xsize ysize

begin texpreamble
    \usepackage{textcomp}
    \newcommand{\murm}{\hbox{\textmu}}
    \usepackage{lmodern}
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 10*pt

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

! graph settings
Tmn=1 ! temperature
Tmx=2.2
Tticks=1
Tsubticks=0.5
numn=0 !frequency
numx=4
nuticks=1
nusubticks=0.5
lambdamn=0 !relaxation
lambdamx=3.5
lambdaticks=1
lambdasubticks=0.5
timn=0 !for A(t) graphs, time should be consistent
timx=3
titicks=1
tisubticks=0.5

xgraphsize=5
ygraphsize=5
xbiggraphsize=7

xoffset=-0.7
yoffset=3.5

ticklength=0.1

!waterfalloffset=2

glw=2*lw
Aterrw=0.001
errw=glw*2
ms=3.5*pt ! marker size

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Cupyo6BF4
amove 0 0.1
begin graph
    size xbiggraphsize ygraphsize
    
    data CuHF2pyz2OCH3/1_814k.dat d1=c1,c2 d2=c1,c3
    
    xtitle "\tex{$t$ (\murm s)}"
    xaxis min timn max timx dticks titicks dsubticks tisubticks
    xaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    !xlabels off
    
    ytitle "\tex{$A(t)$ (\%)}"
    yaxis min 14 max 20 dticks 1 dsubticks 0.5 !nolast
    yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    ysubticks off
    ylabels off
    
    d1 err d2 errwidth Aterrw lwidth lw color rgb(0,0.1,0.25)
end graph

begin key
 pos tr nobox
 text "\tex{(a)}"
end key

begin key
 pos tl nobox
 text "\tex{[Cu(HF$_2$)(pyz)$_2$]OCH$_3$}"
end key

begin graph
    size xbiggraphsize ygraphsize
    
    data CuHF2pyz2OCH3/1_814k.tab d1=c1,c2
    
    xaxis min timn max timx
    xaxis off
    
    yaxis min 14 max 20
    yaxis off
    
    d1 line lwidth glw color rgb(0.25,0.65,1)
end graph


rmove xbiggraphsize+xoffset 0
begin graph
    size xgraphsize ygraphsize
    
    data CuHF2pyz2OCH3/hco_fit_2.dat d1=c1,c3 d2=c1,c4
    data CuHF2pyz2OCH3/hco_fit_2.tab d3=c1,c2
    let d4=d3*0.52533
    
    xtitle "\tex{$T$ (K)}"
    xaxis min Tmn max Tmx dticks Tticks dsubticks Tsubticks
    xaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    !xlabels off
    !xsubticks off
    
    ytitle "\tex{$\nu$ (MHz)}" dist 0.000001
    yaxis min numn max numx dticks nuticks dsubticks nusubticks !nolast
    yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    !ysubticks off
    
    d1 marker fcircle err d2 msize ms errwidth errw lwidth lw
    d3 line lwidth glw color rgb255(48,80,248)
    d4 lstyle 5 lwidth glw color rgb255(255,13,13)
end graph

begin key
 pos tr nobox
 text "\tex{(b)}"
end key

rmove xgraphsize+xoffset+10*pt 0
begin graph
    size xgraphsize ygraphsize
    
    data CuHF2pyz2OCH3/hco_fit_2.dat d1=c1,c5 d2=c1,c6 d3=c1,c7 d4=c1,c8 !d5=c1,c9 d6=c1,c10

    xtitle "\tex{$T$ (K)}"
    xaxis min Tmn max Tmx dticks Tticks dsubticks Tsubticks
    xaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    !xlabels off
    !xsubticks off
    
    ytitle "\tex{$\lambda$ (MHz)}" dist 0.1
    yaxis min lambdamn max lambdamx dticks lambdaticks dsubticks lambdasubticks !nolast
    yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    !ysubticks off
    
    d1 marker fcircle err d2 msize ms color rgb255(48,80,248) errwidth erw lwidth lw
    d3 marker wcircle err d4 msize ms color rgb255(255,13,13) errwidth erw lwidth lw
    !d5 marker ftriangle err d6 msize ms color rgb255(144,224,80) errwidth erw lwidth lw
end graph

begin key
 pos tr nobox
 text "\tex{(c)}"
end key