xsize=12
ysize=10
size xsize ysize
pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
tt=4*pt   !tick length
lw=0.5*pt !line width
glw=2*lw  !graph line width
ms=4*pt   !marker size

! graph settings
xmn=0
xmx=1000
xticks=100
xsubticks=50
ymn=0
ymx=0.005
yticks=0.001
ysubticks=0.0005

set lwidth lw
set hei fs
set just tl

! funky LaTeX commands
begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load-configurations=abbreviations]{siunitx}
    \usepackage{textcomp}
    \newcommand{\murm}{%
      \ifmmode
        \mathchoice
            {\hbox{\normalsize\textmu}}
            {\hbox{\normalsize\textmu}}
            {\hbox{\scriptsize\textmu}}
            {\hbox{\tiny\textmu}}%
      \else
        \textmu
      \fi
    }
    \usepackage{bm}
end texpreamble

! set the normal font to AvantGarde-Demi, which is really obviously
! different to Palatino, so you can spot it if you forget to wrap
! text in \tex{}
set font psagd 

glw=2*lw

begin graph
 size xsize ysize
 scale auto
 nobox
 
 data "MnO-C2-unconstrained.tsv" d1=c1,c2
 data "MnO-C2-O-constraint.tsv" d2=c1,c2
 data "MnO-C2-Mn-weak-constraint.tsv" d3=c1,c2
 data "MnO-C2-interstitial.tsv" d4=c1,c2
  
 xtitle "\tex{$\nu$ (\si{\MHz})}"
 xaxis min xmn max xmx dticks xticks dsubticks xsubticks
 xaxis format "round 1 prepend \tex{$ append $}"
 xticks length tt
 
 ytitle "\tex{$f(\nu )$ (\si{\per\MHz})}"
 yaxis min ymn max ymx dticks yticks dsubticks ysubticks
 yaxis format "round 1 prepend \tex{$ append $}"
 yticks length tt
 
 d1 lstyle 2 lwidth glw color black
 d2 lstyle 1 lwidth glw color rgb255(255,13,13)
 d3 deresolve 2 average lstyle 3 lwidth glw color rgb255(156,122,199)
 d4 deresolve 2 average lstyle 5 lwidth glw color rgb255(48,80,248)
 
 let d10=2 from 215 to 225
 fill x1,d10 color rgb255(200,240,168)
end graph

begin key
 text "\tex{$\bm{r}_{\murm}$ unconstrained}" lstyle 2 color black lwidth glw
 text "\tex{$\num{0.09}\leq r_{\murm\text{--O}}\leq \SI{0.11}{\nm}$}" lstyle 1 color rgb255(255,13,13) lwidth glw
 text "\tex{...\& $r_{\murm\text{--Mn}}> \SI{0.17}{\nm}$}" lstyle 3 color rgb255(156,122,199) lwidth glw
 text "\tex{$r_{\murm\text{--any}}> \SI{0.17}{\nm}$}" lstyle 5 color rgb255(48,80,248) lwidth glw
end key

amove 3.75 1.6
rotate 90
tex "\SI{220}{\MHz}"