size 11.2 8

pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
lw=0.5*pt !line width

set lwidth lw
set hei fs
set just cl

! funky LaTeX commands
begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage{textcomp}
    \newcommand{\murm}{%
      \ifmmode
        \mathchoice
            {\hbox{\normalsize\textmu}}
            {\hbox{\normalsize\textmu}}
            {\hbox{\scriptsize\textmu}}
            {\hbox{\tiny\textmu}}%
      \else
        \textmu
      \fi
    }
end texpreamble

! set the normal font to AvantGarde-Demi, which is really obviously
! different to Palatino, so you can spot it if you forget to wrap
! text in \tex{}
set font psagd 

begin translate -11 -6

r=3 !circle size
z=4 !grid size

sub cardi a
    set lwidth 2*pt
    set color rgb(0.2,0.7,1)
    amove 15+r*(1+a) 10
    for i=1 to 400
    theta=2*3.1415926535*(i-1)/399
    z=r*(1+a*cos(theta))
    aline 15+z*cos(theta) 10+z*sin(theta)
    next i
end sub


sub grid
    set lwidth 1*pt
    set color rgb(0.8,0.8,0.8)
    for i=1 to 16
    theta=2*3.1415926535*(i-1)/16
    amove 15 10
    aline 15+z*cos(theta) 10+z*sin(theta)
    next i
    amove 15 10
    for i=1 to 4
    circle i
    next i
end sub

!set color blue

@grid
@cardi 1/3

set lwidth 2*pt
set color rgb(1,0.75,0)
amove 15 10
rline 4 0 arrow end

set color black
amove 19.2 10
text \tex{\murm\textsuperscript{+} spin direction}

set lwidth 0.5*pt
set color blue
a=1/3
amove 15+r*(1+a) 10
for i=1 to 23
    theta = 2*3.1415926535*(i-0.5)/(23-1)
    z=r*(1+a*cos(theta))
    amove 15 10
    aline 15+z*cos(theta) 10+z*sin(theta) arrow end
next i

end translate