xsize=8.2
ysize=6.7
size xsize ysize

begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
    \usepackage{bm}
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 11*pt
set texscale scale

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

! graph settings
xmn=0 ! temperature
xmx=0.65
xticks=0.2
xsubticks=0.1
ymn=0 !frequency
ymx=0.5
yticks=0.1
ysubticks=0.05

ticklength=0.1

glw=2*lw
errw=glw*1.2
ms=4*pt ! marker size

xgraphsize=6.9
ygraphsize=6.9


amove 0.2 0
begin graph
    size xgraphsize ygraphsize
    
    data TN-over-J-vs-beta.tsv d1=c1,c3 d2=c1,c4 d3=c1,c2
    data TN-over-J-vs-beta-HF2.tsv d11=c1,c3 d12=c1,c4 d13=c1,c2
    data TN-over-J-vs-beta-othermol.tsv d21=c1,c3 d22=c1,c4 d23=c1,c2
    data TN-over-J-vs-beta-nonmol.tsv d31=c1,c3 d32=c1,c4 d33=c1,c2
    
    xtitle "\tex{$k_{\mathrm{B}}T_{\mathrm{N}}/J$}"
    xaxis min xmn max xmx dticks xticks dsubticks xsubticks
    xaxis format "round 1 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    
    ytitle "\tex{$\beta$}"
    yaxis min ymn max ymx dticks yticks dsubticks ysubticks
    yaxis format "round 1 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    ysubticks off
    
    y2places 0.5 0.367 0.35 0.326 0.125
    y2names "" "" "" "" ""
    
    d1 err d2 herr d3 marker fcircle msize ms color rgb255(128,7,7)
    d11 err d12 herr d13 marker fcircle msize ms color rgb255(255,13,13)
    d21 err d22 herr d23 marker wcircle msize ms color rgb(0.188235,0.313725,0.972549)
    !d31 err d32 herr d33 marker ftriangle msize ms color rgb(0.564706,0.878431,0.313725)
end graph

set hei 8*pt

begin key
 pos tl
 nobox
 offset 0 -0.1
 text "\tex{from this work}" marker fcircle msize ms color rgb255(128,7,7)
 text "\tex{[Cu(HF$_2$)(pyz)$_2$]$X$}" marker fcircle msize ms color rgb(1.000000,0.050980,0.050980)
end key

begin key
 pos tl
 nobox
 offset 3 -0.1
 text "\tex{other molecular}" marker wcircle msize ms color rgb(0.188235,0.313725,0.972549)
 !text "\tex{inorganic systems}" marker ftriangle msize ms color rgb(0.564706,0.878431,0.313725)
end key

set hei 10*pt

begin graph
    size xgraphsize ygraphsize
    
    xaxis off
    yaxis min 0 max 0.5
    ylabels off
    yside off
    yticks off
    
    y2places 0.5 0.375 0.35 0.32 0.125
    y2side off
    y2names "\tex{Landau}" "\tex{3D Heisenberg}" "\tex{3D XY}" "\tex{3D Ising}" "\tex{2D Ising}"
end graph