xsize=8
ysize=9.3
size xsize ysize

begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
    \usepackage{bm}
    \usepackage{textcomp}
    \newcommand{\murm}{%
      \ifmmode
        \mathchoice
            {\hbox{\normalsize\textmu}}
            {\hbox{\normalsize\textmu}}
            {\hbox{\scriptsize\textmu}}
            {\hbox{\tiny\textmu}}%
      \else
        \textmu
      \fi
    }
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 12*pt
set texscale scale

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

! graph settings
xmn=0
xmx=10
ymn=0
ymx=0.3

xgraphsize=9
ygraphsize=4.5
glw=2*lw


! near anions' F or O

amove 0 ygraphsize+0.6
begin graph
 size xgraphsize ygraphsize
 nobox
 xtitle "\tex{$\nu /\mu$ (MHz$\cdot\mu _{\mathrm{B}}^{-1}$)}"
 ytitle "\tex{$f(\nu / \mu)$ ($\mu _{\mathrm{B}}\cdot$MHz$^{-1}$)}"
 xaxis min xmn max xmx dticks 2 dsubticks 1
 xaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 xticks length tt
 yaxis min ymn max ymx dticks 0.1 dsubticks 0.05
 yaxis format "fix 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt
 
 data BF4-nearpyz/nearpyz.tsv d1=c1,c2
 data BF4-nearpyz/nearpyz.tsv d2=c1,c3
 data BF4-nearpyz/nearpyz.tsv d3=c1,c4
 d1 deresolve 3 color rgb255(48,80,248) lwidth glw lstyle 3  ! 'cold' blue, short dashes
 d2 deresolve 3 average smooth color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 5  ! F colour, long dashes
 d3 deresolve 3 average smooth color rgb(1.000000,0.050980,0.050980) lwidth glw lstyle 1  ! 'hot' red, solid line
end graph

begin key
 position tr nobox
 llen 0.79
 text "(i)" color rgb(1.000000,0.050980,0.050980) lwidth glw lstyle 1
 text "(ii)" color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 5
 text "(iii)" color rgb255(48,80,248) lwidth glw lstyle 3
end key

begin key
 position tl
 nobox
 text "\tex{(a)}"
end key

! graph settings
xmn=0
xmx=1
ymn=0
ymx=7

amove 0 0.4
begin graph
 size xgraphsize ygraphsize
 nobox
 xtitle "\tex{$\mu$ ($\mu_{\mathrm{B}}$)}"
 ytitle "\tex{$g(\mu | \{\nu _i \})$ ($\mu_{\mathrm{B}}^{-1}$)}"
 xaxis min xmn max xmx dticks 0.5 dsubticks 0.1
 xaxis format "fix 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 xticks length tt
 yaxis min ymn max ymx dticks 2 dsubticks 1
 yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt
 
 data muCu-pdf/CuHF2pyz2BF4-AFM1.tsv d1=c1,c2
 data muCu-pdf/CuHF2pyz2BF4-AFM4.tsv d2=c1,c2
 data muCu-pdf/CuHF2pyz2BF4-AFM7.tsv d3=c1,c2
 d1 color rgb255(48,80,248) lwidth glw lstyle 3  ! 'cold' blue, short dashes
 d2 color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 5  ! F colour, long dashes
 d3 color rgb(1.000000,0.050980,0.050980) lwidth glw lstyle 1  ! 'hot' red, solid line
end graph

begin key
 position tl
 nobox
 text "\tex{(b)}"
end key