xsize=10
ysize=8
size xsize ysize

begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
    \usepackage{bm}
end texpreamble

pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
tt=4*pt   !tick length
lw=0.5*pt !line width
glw=2*lw  !graph line width
ms=4*pt   !marker size

set hei fs
set lwidth lw
set just tl


! graph settings
xmn=0
xmx=8.5
ymn=0
ymx=4.5

prop=2.52 !the constant of proportionality between the frequencies

amove 0 0
begin graph
 size xsize ysize
 nobox
 scale auto
 xtitle "\tex{$T$ (K)}"
 ytitle "\tex{$\nu$ (MHz)}"
 data try5-analyse.dat d1=c4,c5 d2=c4,c6
 let d1=d1*prop !numbers reordered to alter z-order of lines
 let d2=d2*prop !numbers reordered to alter z-order of lines
 data meanfield-bestfit.dat d5=c1,c2
 let d5=d5*prop
 d5 line color black lstyle 4 lwidth glw/2
 data kuzmin-bestfit.dat d6=c1,c2
 let d6=d6*prop
 d6 line color black lwidth glw
 data alphabeta-bestfit.dat d7=c1,c2
 let d7=d7*prop
 d7 line color rgb(0,0.788235,0) lstyle 3 lwidth glw/2
 xaxis min xmn max xmx dticks 2 dsubticks 1
 xaxis format "fix 0 prepend \tex{$ append $}"
 xticks length tt
 yaxis min ymn max ymx dticks 1 dsubticks 0.5
 yaxis format "fix 0 prepend \tex{$ append $}"
 yticks length tt
 d1 marker fcircle err d2 msize ms
end graph

set just tl

smalloffset=0.045 ! add slight offset so this line is centred on those below
amove 1.5+smalloffset 3
set color black
set lstyle 4
rline 0.95-smalloffset 0 ! and make the line slightly shorter
set lstyle 0 lwidth glw/2
rmove 0.2 0.15
text \tex{mean field}

amove 1.5 2.3
set color rgb(0,0.788235,0)
set lstyle 3
rline 0.95 0
set lstyle 0 lwidth glw/2
rmove 0.2 0.3 !add a bit extra because this is mainly lower case
text \tex{$\nu(0)\left(1-\left({T}/{T_{\mathrm{c}}}\right)^{\alpha}\right)^\beta$}

amove 1.5 1.6
set color black
set lstyle 0
set lwidth glw
rline 0.95 0
rmove 0.2 0.15
text \tex{Kuz'min formula}
