xsize=15
ysize=8
size xsize ysize
pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
tt=4*pt   !tick length
lw=0.5*pt !line width
glw=2*lw  !graph line width
ms=4*pt   !marker size

include "polarplot.gle"

pi=3.14159265358979323

! radii of field lines to make them correct
r1=0.1*1^3
r2=0.1*2^3
r3=0.1*3^3
r4=0.1*4^3
r5=0.1*5^3
r6=0.1*6^3

gmin=-5
gmax=5

!set texlabels 1
!set texscale scale
set color gray50
amove -1 -1
begin graph
    size 8 10
    xaxis min gmin max gmax
    yaxis min gmin max gmax
    xaxis off
    yaxis off
    polar "r1*(sin(t-pi/2)^2)" 0 2*pi color gray50
    polar "r2*(sin(t-pi/2)^2)" 0 2*pi color gray50
    polar "r3*(sin(t-pi/2)^2)" 0 2*pi color gray50
    polar "r4*(sin(t-pi/2)^2)" 0 2*pi color gray50
    polar "r5*(sin(t-pi/2)^2)" 0 2*pi color gray50
    polar "r6*(sin(t-pi/2)^2)" 0 2*pi color gray50
    let d1=9e9*x
    d1 line lwidth lw color gray50
end graph

! draw arrows
set arrowsize 0.15
amove xg(r2) yg(0)
rline 0 -0.1 arrow end
amove xg(-r2) yg(0)
rline 0 -0.1 arrow end

! draw dipole
set color rgb255(255,13,13)
set lwidth 2.5*pt
set arrowangle 18
set arrowsize 0.35
amove xg(0) yg(0)
rline 0 0.6 arrow end
set color rgb255(48,80,248)
amove xg(0) yg(0)
rline 0 -0.5