xsize=8
ysize=15.1
size xsize ysize

begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
    \usepackage{bm}
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 11*pt
set texscale scale

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

ms=4*pt

graphypos=-2.8
graphysize=20

ymin=0.1
ymax=0.65

set just bc

amove 0.85 15.1-10*pt
text \tex{$\xi /a$}
amove 2.1 13.4
text \tex{$J_{\perp}/J$}
amove 3.4 14.5
text \tex{$k_{\mathrm{B}}T_{\mathrm{N}}/J$}

amove 3.2 graphypos
begin graph
   size 1.5 graphysize
   yaxis min ymin max ymax format "fix 1 prepend \tex{$ append $}"
   xaxis min 0 max 2
   xaxis off
   !ytitle "\tex{$k_{\mathrm{B}}T_{\mathrm{N}}/J$}"
   
   y2axis off
   
end graph

! stuff from this paper
set color rgb(1.000000,0.050980,0.050980)
begin graph
   size 1.5 graphysize
   yaxis min ymin max ymax
   yaxis off
   xaxis min 0 max 2
   xaxis off
   
   data "TN-over-J-thispaper-modified.tsv" d1=c1,c2 d2=c1,c3 d3=c2,c4 comment #

   y2axis on
   y2side off
   y2ticks off
   y2places 0.25 0.263 0.345 0.332 0.319 0.593319269 0.423136313 0.144357298
   y2names "\tex{[Cu(HF$_2$)(pyz)$_2$]BF$_4$}" "\tex{[Cu(HF$_2$)(pyz)$_2$]ClO$_4$}" "\tex{[Cu(HF$_2$)(pyz)$_2$]PF$_6$}" "\tex{[Cu(HF$_2$)(pyz)$_2$]AsF$_6$}" "\tex{[Cu(HF$_2$)(pyz)$_2$]SbF$_6$}" "\tex{[Cu(pyo)$_6$](BF$_4$)$_2$}" "\tex{[Cu(pyo)$_2$(pyz)$_2$](PF$_6$)$_2$}" "\tex{Ag(pyz)$_2$(S$_2$O$_8$)}"

   
   d1 err d2 marker fcircle msize ms color rgb(1.000000,0.050980,0.050980)
end graph

! other molecular materials
set color rgb(0.188235,0.313725,0.972549)
begin graph
   size 1.5 graphysize
   yaxis min ymin max ymax
   yaxis off
   xaxis min 0 max 2
   xaxis off
   
   data "TN-over-J-other-modified.tsv" d1=c1,c2 d2=c1,c3 d3=c2,c4 comment #

   y2axis on
   y2side off
   y2ticks off
   y2places 0.237 0.211 0.576368876081
   y2names "\tex{[Cu(pyz)$_2$](ClO$_4$)$_2$}" "\tex{CuF$_2$(H$_2$O)$_2$(pyz)}" "\tex{(5BAP)$_2$CuBr$_4$}"
   
   d1 err d2 marker wcircle msize ms color rgb(0.188235,0.313725,0.972549)
end graph

! famous 2D model systems
set color rgb(0.564706,0.878431,0.313725)
begin graph
   size 1.5 graphysize
   yaxis min ymin max ymax
   yaxis off
   xaxis min 0 max 2
   xaxis off
   
   data "TN-over-J-nonmol.tsv" d1=c1,c2 d2=c1,c3 d3=c2,c4 comment #

   y2axis on
   y2side off
   y2ticks off
   y2places 0.224 0.176827874069 !0.35
   y2names "\tex{La$_2$CuO$_4$}" "\tex{Sr$_2$CuO$_2$Cl$_2$}" !"\tex{Ca$_{0.85}$Sr$_{0.15}$CuO$_2$}"

   
   !d1 marker ftriangle msize ms
   d1 err d2 marker ftriangle msize ms color rgb(0.564706,0.878431,0.313725)
end graph

set color rgb(0.7,0.7,0.7)
! J'/J axis
amove 2.1 graphypos
begin graph
   size 1 graphysize
   yaxis min ymin max ymax
   xaxis min 0 max 2
   xaxis off
   !ytitle "\tex{$J_{\perp}/J$}"
   
   yplaces 0.164932806 0.141555774 0.123982853
   ynames "\tex{$10^{-4}$}" "\tex{$10^{-5}$}" "\tex{$10^{-6}$}" "\tex{$10^{-7}$}"
   
   yside off
   ysubticks off
   
   y2axis off
end graph

!grey axis
amove xg(0) yg(0.246273944)
aline xg(0) yg(0.123982853)

set color black
! J'/J axis
amove 2.1 graphypos
begin graph
   size 1 graphysize
   yaxis min ymin max ymax
   xaxis min 0 max 2
   xaxis off
   !ytitle "\tex{$J_{\perp}/J$}"
   
   yplaces 0.60258607 0.48591748 0.326878492 0.246273944
   ynames "\tex{$0.25$}" "\tex{$10^{-1}$}" "\tex{$10^{-2}$}" "\tex{$10^{-3}$}"
   
   yside off
   ysubticks off
   
   y2axis off
end graph

!black axis
amove xg(0) yg(0.60258607)
aline xg(0) yg(0.246273944)



set color black
! correlation length axis
amove 0.8 graphypos
begin graph
   size 1 graphysize
   yaxis min ymin max ymax
   xaxis min 0 max 2
   xaxis off
   !ytitle "\tex{$\xi /a$}"
   
   yplaces 0.653912662001 0.54620779732 0.447743055376 0.356728136648 0.295146613825 0.239589286566 0.209482231399 0.185993638642 0.161902975357 0.147419676833 0.113568385728
   ynames "\tex{$2$}" "\tex{$3$}" "\tex{$5$}" "\tex{$10$}" "\tex{$20$}" "\tex{$50$}" "\tex{$100$}" "\tex{$200$}" "\tex{$500$}" "\tex{$1000$}" "\tex{$10000$}"
  
   yside off  
   ysubticks off
   
   y2axis off
end graph

!black axis
amove xg(0) yg(0.113568385728)
aline xg(0) yg(0.653912662001)

amove 7.3 14.2
begin graph
  size 1 1
  xaxis off
  yaxis off
end graph

begin key
 pos tr
 offset 0.01 0
 text "\tex{from this work}" marker fcircle msize ms color rgb(1.000000,0.050980,0.050980)
 text "\tex{other molecular}" marker wcircle msize ms color rgb(0.188235,0.313725,0.972549)
 text "\tex{inorganic systems}" marker ftriangle msize ms color rgb(0.564706,0.878431,0.313725)
end key
  