xsize=15.7
ysize=6.3
size xsize ysize

begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
    \usepackage{bm}
    \usepackage{textcomp}
    \newcommand{\murm}{%
      \ifmmode
        \mathchoice
            {\hbox{\normalsize\textmu}}
            {\hbox{\normalsize\textmu}}
            {\hbox{\scriptsize\textmu}}
            {\hbox{\tiny\textmu}}%
      \else
        \textmu
      \fi
    }
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 12*pt
set texscale scale

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

! graph settings
timn=0 !for A(t) graphs, time should be consistent
timx=0.8
titicks=0.2
tisubticks=0.1
Atmn=-20
Atmx=20
Atticks=5
Aterrw=0.001


xgraphsize=5
ygraphsize=5
xbiggraphsize=7
ybiggraphsize=3.5

xoffset=-0.5
yoffset=3.5

xstart=-0.3
ystart=1

ticklength=0.1

!waterfalloffset=2

glw=lw*1.5
errw=glw*2
ms=3.5*pt ! marker size

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
amove xstart 2.95
begin graph
    size xbiggraphsize ybiggraphsize
    
    data 2_5k.dat d1=c1,c2 d2=c1,c3
    
    !xtitle "\tex{$t$ (\si{\us})}"
    xaxis min timn max timx dticks titicks dsubticks tisubticks
    xaxis format "round 2 nozeroes prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    xlabels off
    
    ytitle "\tex{$A(t)$ (arb.)}"
    yaxis min Atmn max Atmx dticks Atticks
    yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    ysubticks off
    ylabels off
    
    d1 err d2 errwidth Aterrw lwidth lw color rgb(0.25,0,0)
end graph

begin key
 pos tr nobox
 text "\tex{(a)}"
end key

begin key
 pos tl nobox
 text "\tex{$B=2\mathrm{\; T}$}"
end key

begin key
 pos br nobox
 text "\tex{$T=2.5\mathrm{\; K}$}"
end key

begin graph
    size xbiggraphsize ybiggraphsize
    
    data 1383-stuff d1=c1,c4
    
    xaxis min timn max timx
    xaxis off
    
    yaxis min Atmn max Atmx dticks Atticks
    yaxis off
    
    d1 line lwidth glw color rgb(1,0.05098,0.05098)
end graph

amove xstart 0.5
begin graph
    size xbiggraphsize ybiggraphsize
    
    data 1_5k.dat d1=c1,c2 d2=c1,c3
    
    xtitle "\tex{$t$ (\si{\us})}"
    xaxis min timn max timx dticks titicks dsubticks tisubticks
    xaxis format "round 2 nozeroes prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    !xlabels off
    
    ytitle "\tex{$A(t)$ (arb.)}"
    yaxis min Atmn max Atmx dticks Atticks
    yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    ysubticks off
    ylabels off
    
    d1 err d2 errwidth Aterrw lwidth lw color rgb(0,0.1,0.25)
end graph

begin graph
    size xbiggraphsize ybiggraphsize
    
    data 1372-stuff d1=c1,c4
    
    xaxis min timn max timx
    xaxis off
    
    yaxis min Atmn max Atmx dticks Atticks
    yaxis off
    
    d1 line lwidth glw color rgb(0.25,0.65,1)
end graph

begin key
 pos tr nobox
 text "\tex{(b)}"
end key

begin key
 pos tl nobox
 text "\tex{$B=2\mathrm{\; T}$}"
end key

begin key
 pos br nobox
 text "\tex{$T=1.5\mathrm{\; K}$}"
end key

Tmn=1.4 ! temperature
Tmx=2.6
Tticks=0.5
Tsubticks=0.1
sigmn=0.8 !sigma
sigmx=2.2
sigticks=0.5
sigsubticks=0.1

amove xstart ystart

rmove xbiggraphsize+xoffset+0.2 0
begin graph
    size xgraphsize ygraphsize
    
    data tdep.dat d1=c4,c7 d2=c4,c8
    data tdep.tab d3=c1,c2
    
    xtitle "\tex{$T$ (K)}"
    xaxis min Tmn max Tmx dticks Tticks dsubticks Tsubticks
    xaxis format "round 2 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    !xlabels off
    !xsubticks off
    
    ytitle "\tex{$\sigma$ (MHz)}" dist 0.1
    yaxis min sigmn max sigmx dticks sigticks dsubticks sigsubticks !nolast
    yaxis format "fix 1 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    !ysubticks off
    
    d1 marker fcircle err d2 msize ms errwidth 0.05 lwidth 0.01
    d3 line lwidth glw color rgb(1,0.05098,0.05098)
end graph

begin key
 pos tr nobox
 text "\tex{(c)}"
end key

begin key
 pos tl nobox
 offset 0.3 0
 text "\tex{$B=2\mathrm{\; T}$}"
end key


Tmn=1.4 ! temperature
Tmx=2.3
Tticks=0.5
Tsubticks=0.1
Bmn=0 !relaxation
Bmx=15
Bticks=5
Bsubticks=1

ms=4*pt

rmove xgraphsize+xoffset+10*pt+0.2 0
begin graph
    size xgraphsize ygraphsize
    
    data exp2.dat d2=c1,c2 d5=c1,c3
    data theory.dat d1=c1,c2
    data muon.dat d3=c1,c2 d4=c1,c3
    data muon-Bscan.dat d6=c1,c2 d7=c1,c3
    
    xtitle "\tex{$T$ (K)}"
    xaxis min Tmn max Tmx dticks Tticks dsubticks Tsubticks
    xaxis format "fix 1 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    xticks length ticklength
    !xlabels off
    !xsubticks off
    
    ytitle "\tex{$B$ (T)}" dist 0.1
    yaxis min Bmn max Bmx dticks Bticks dsubticks Bsubticks !nolast
    yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. dec is just padding, because for some reason it doesn't work if prepend or append is first
    yticks length ticklength
    !ysubticks off
    
    d2 marker square msize ms color rgb255(48,80,248) herr d5
    d1 marker fcircle msize ms color rgb255(144,224,80)
    d3 marker fcircle msize ms color rgb(1,0.05098,0.05098) herr d4
    d6 marker fcircle msize ms color rgb(1,0.05098,0.05098) err d7
end graph

begin key
 pos tr nobox
 text "\tex{(d)}"
end key


set hei 8*pt
begin key
 pos bl
 offset 0.2 0.94
 marker square msize ms color rgb255(48,80,248) text "\tex{HC}"
 marker fcircle msize ms color rgb255(144,224,80) text "\tex{theory}"
 marker fcircle msize ms color rgb(1,0.05098,0.05098) text "\tex{\murm $^+$SR}"
end key