xsize=8
ysize=12.4
size xsize ysize

begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
    \usepackage{bm}
    \usepackage{textcomp}
    \newcommand{\murm}{%
      \ifmmode
        \mathchoice
            {\hbox{\normalsize\textmu}}
            {\hbox{\normalsize\textmu}}
            {\hbox{\scriptsize\textmu}}
            {\hbox{\tiny\textmu}}%
      \else
        \textmu
      \fi
    }
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 12*pt
set texscale scale

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

! graph settings
xmn=0
xmx=10
ymn=0
ymx=0.5

xgraphsize=9
ygraphsize=4.5
glw=2*lw

hw=0.2

! near anions' F or O

amove 0 3.15+3.65
begin graph
 size xgraphsize ygraphsize
 nobox
 !xtitle "\tex{$\nu$ (MHz)}"
 !ytitle "\tex{$f(\nu)$ (MHz$^{-1}$)}"
 xaxis min xmn max xmx dticks 5 dsubticks 1
 xaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 xticks length tt
 xlabels off
 yaxis min ymn max ymx dticks 0.2 dsubticks 0.1
 yaxis format "fix 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt
 data X-nearvarious/bf4-near-bf4.tsv d1=c1,c2
 data X-nearvarious/clo4-near-clo4.tsv d2=c1,c2
 data X-nearvarious/pf6-near-pf6.tsv d3=c1,c2
 d1 color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 1  ! F colour, solid line = BF4
 d2 color rgb(1.000000,0.050980,0.050980) lwidth glw lstyle 3  ! O colour, short dashes = ClO4
 d3 color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 5  ! F colour, long dashes = PF6
 
 ! filled areas for desired frequencies
 let d21 = 1 from 0.95-hw to 0.95+hw ! BF4 frequencies
 let d22 = 1 from 3.3-hw to 3.3+hw
 let d23 = 1 from 2.23-hw to 2.23+hw ! PF6 frequencies
 let d24 = 1 from 3.89-hw to 3.89+hw
 fill x1,d21 color rgb255(255,206,206)
 fill x1,d22 color rgb255(255,206,206)
 fill x1,d23 color rgb255(204,204,255)
 fill x1,d24 color rgb255(204,204,255)
end graph

begin key
 pos tr nobox
 text "\tex{near anions}"
end key

begin key
 pos tl nobox
 offset 0 -0.05
 llen 0.79
 lstyle 1 lwidth glw text "\tex{BF$_4$}"
 lstyle 3 lwidth glw text "\tex{ClO$_4$}"
 lstyle 5 lwidth glw text "\tex{PF$_6$}"
end key

begin key
 pos tr nobox
 offset 0 -0.05
 llen 0.79
 lstyle 1 lwidth glw color rgb(0.564706,0.878431,0.313726) text "\tex{near F}"
 lstyle 1 lwidth glw color rgb(1.000000,0.050980,0.050980) text "\tex{near O}"
 lstyle 1 lwidth glw color rgb255(100,100,100) text "\tex{near C or N}"
end key


! near HF2 fluorines

amove 0 3.65
begin graph
 size xgraphsize ygraphsize
 nobox
 !xtitle "\tex{$\nu$ (MHz)}"
 ytitle "\tex{$f(\nu)$ (MHz$^{-1}$)}"
 xaxis min xmn max xmx dticks 5 dsubticks 1
 xaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 xticks length tt
 xlabels off
 yaxis min ymn max ymx dticks 0.2 dsubticks 0.1
 yaxis format "fix 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt
 data X-nearvarious/bf4-near-hf2.tsv d1=c1,c2
 data X-nearvarious/clo4-near-hf2.tsv d2=c1,c2
 data X-nearvarious/pf6-near-hf2.tsv d3=c1,c2
 d1 color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 1  ! F colour, solid line = BF4
 d2 color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 3  ! F colour, short dashes = ClO4
 d3 color rgb(0.564706,0.878431,0.313726) lwidth glw lstyle 5  ! F colour, long dashes = PF6
 
 ! filled areas for desired frequencies
 let d21 = 1 from 0.95-hw to 0.95+hw ! BF4 frequencies
 let d22 = 1 from 3.3-hw to 3.3+hw
 let d23 = 1 from 2.23-hw to 2.23+hw ! PF6 frequencies
 let d24 = 1 from 3.89-hw to 3.89+hw
 fill x1,d21 color rgb255(255,206,206)
 fill x1,d22 color rgb255(255,206,206)
 fill x1,d23 color rgb255(204,204,255)
 fill x1,d24 color rgb255(204,204,255)
end graph

begin key
 pos tr nobox
 text "\tex{near HF$_{2}$}"
end key

! other possible muon sites

amove 0 0.5
begin graph
 size xgraphsize ygraphsize
 nobox
 xtitle "\tex{$\nu$ (MHz)}"
 !ytitle "\tex{$f(\nu)$ (MHz$^{-1}$)}"
 xaxis min xmn max xmx dticks 5 dsubticks 1
 xaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 xticks length tt
 !xlabels off
 yaxis min ymn max ymx dticks 0.2 dsubticks 0.1
 yaxis format "fix 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt
 data X-nearvarious/bf4-near-pyz.tsv d1=c1,c2
 data X-nearvarious/clo4-near-pyz.tsv d2=c1,c2
 data X-nearvarious/pf6-near-pyz.tsv d3=c1,c2
 d1 color rgb255(100,100,100) lwidth glw lstyle 1  ! N colour, solid line = BF4
 d2 color rgb255(100,100,100) lwidth glw lstyle 3  ! N colour, short dashes = ClO4
 d3 color rgb255(100,100,100) lwidth glw lstyle 5  ! N colour, long dashes = PF6
 
 ! filled areas for desired frequencies
 let d21 = 1 from 0.95-hw to 0.95+hw ! BF4 frequencies
 let d22 = 1 from 3.3-hw to 3.3+hw
 let d23 = 1 from 2.23-hw to 2.23+hw ! PF6 frequencies
 let d24 = 1 from 3.89-hw to 3.89+hw
 fill x1,d21 color rgb255(255,206,206)
 fill x1,d22 color rgb255(255,206,206)
 fill x1,d23 color rgb255(204,204,255)
 fill x1,d24 color rgb255(204,204,255)
end graph

begin key
 pos tr nobox
 text "\tex{near pyz}"
end key

set hei 8*pt

amove 2.05 5.2
begin rotate 90
 text \tex{$\nu ^{\mathrm{BF_4}} _{2}$}
end rotate
amove 2.85 6
begin rotate 90
 text \tex{$\nu ^{\mathrm{PF_6}} _{2}$}
end rotate
amove 3.45 5.2
begin rotate 90
 text \tex{$\nu ^{\mathrm{BF_4}} _{1}$}
end rotate
amove 4 6
begin rotate 90
 text \tex{$\nu ^{\mathrm{PF_6}} _{1}$}
end rotate