xsize=8
ysize=6
size xsize ysize

begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
    \usepackage{bm}
    \usepackage{textcomp}
    \newcommand{\murm}{\hbox{\textmu}}
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 11*pt
set texscale scale

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

! graph settings
xmn=0
xmx=9
ymn=4
ymx=13
xticks=2
xsubticks=1
yticks=5
ysubticks=1

xoffset=0
yoffset=0

ticklength=0.1

!waterfalloffset=2

glw=2*lw
Aterrw=0.001
errw=glw*2
ms=3.5*pt ! marker size

amove xoffset yoffset
begin graph
    size xsize ysize
    scale auto
    xtitle "\tex{$T$ (K)}"
    xaxis min xmn max xmx dticks xticks dsubticks xsubticks
    xticks length tt
    
    ytitle "\tex{$A(t > \SI{5}{\us})$ (\si{\percent})}"
    yaxis min ymn max ymx hei hh dticks yticks dsubticks ysubticks
    !ysubticks off
    !ylabels off
    yticks length tt
    
    data NiPF6/try4-baselines.dat d1=c4,c5 d2=c4,c6
    data NiPF6/try4-baselines.tab d4=c1,c2
    d1 marker wcircle err d2 msize ms
    d4 line lwidth lw color rgb255(255,13,13)
    let d5 = 1000 from 6.2 to 6.3 ! Tc from specific heat
    fill x1,d5 color rgb(0.6,1,0.6)
    let d6 = 1000 from 6.1 to 6.2 ! Tc from specific heat overlapping with muSR estimate
    fill x1,d6 color rgb(0.3,0.7,0.6)
    let d7 = 1000 from 5.5 to 6.1 ! Tc range from muSR fit
    fill x1,d7 color rgb(0.7,0.7,1)
end graph

amove 4.8 1.7
set color rgb(0,0,1)
begin rotate 90
 text \tex{\murm $^+$SR $\Delta T_{\mathrm{N}}$}
end rotate

amove 5.95 4.2
set color rgb(0,0.8,0)
begin rotate 90
 text \tex{SHC $\Delta T_{\mathrm{N}}$}
end rotate