xsize=8
ysize=5
size xsize ysize

begin texpreamble
    \usepackage{textcomp}
    \newcommand{\murm}{\hbox{\textmu}}
    \usepackage{lmodern}
end texpreamble

pt=0.0352777778 ! 1 postscript point

set font texcmr
set hei 12*pt

tt=4*pt
lw=0.5*pt
set lwidth lw
set just tl

! graph settings
xmn=-70000
xmx=70000
ymn=-0.25
ymx=0.25

xgraphsize=5.6
ygraphsize=3.1
xgraphpos=3.2
ygraphpos=2.3
glw=2*lw
ms=3*pt

! some constants
emutomuBfuLi=3.31
emutomuBfuNa=2.969990096
pulsedtomuB_25T = 12100
pulsedtomuB_45T = 12200

set hei 8*pt


!fake x-axis for tightness
amove xgraphpos ygraphpos+0.05
begin graph
 size xgraphsize ygraphsize
 nobox
 xtitle "\tex{$B$ (T)}" dist -0.001
 xaxis min xmn max xmx
 xticks off
 xsubticks off
 xside off
 xplaces -60000 -40000 -20000 0 20000 40000 60000
 xnames \tex{$-6$} \tex{$-4$} \tex{$-2$} \tex{$0$} \tex{$2$} \tex{$4$} \tex{$6$}
 yaxis off
end graph


amove xgraphpos ygraphpos
begin graph
 size xgraphsize ygraphsize
 nobox
 !xtitle "\tex{$B$ (T)}"
 ytitle "\tex{$M$ ($\mu _{\mathrm{B}}$/f.u.)}" dist -0.0001
 xlabels off
 xaxis min xmn max xmx! dsubticks 10000
 !xplaces -60000 -40000 -20000 0 20000 40000 60000
 !xnames \tex{$-6$} \tex{$-4$} \tex{$-2$} \tex{$0$} \tex{$2$} \tex{$4$} \tex{$6$}
 xticks length tt
 yaxis min ymn max ymx dticks 0.1 dsubticks 0.05
 yaxis format "round 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt

 data Ba2LiOsO6-6.dc.dat d1=c2,c4 d2=c2,c5 ! Li M(B)
 data BNOO-3.dc.dat d3=c2,c4 d4=c2,c5 ! Na M(B)
 let d1=d1*emutomuBfuLi
 let d2=d2*emutomuBfuLi
 let d3=d3*emutomuBfuNa
 let d4=d4*emutomuBfuNa

 d1 color rgb(0.196078431,0,0.376470588) marker wcircle msize ms err d2  ! Li dark purple
 d3 color rgb(0.584314,0.223529,0.898039) marker fsquare msize ms/1.5 err d4  ! Na light purple
end graph

begin key
 nobox
 position tl
 text "\tex{(b)}"
end key

! Ba2LiOsO6 hysteresis arrows/label
set color rgb(0.196078431,0,0.376470588)
amove 4.8 3.34
rline 0.2 0.34 arrow end
amove 4.23 3.45
rline 0.2 0.34 arrow start
amove 7.65 3.9
rline 0.2 0.34 arrow end
amove 7.04 4.09
rline 0.2 0.34 arrow start
amove 4.4 3.85
begin rotate 4.5
 text \tex{Ba$_2$LiOsO$_6$}
end rotate
! Ba2NaOsO6 label
set color rgb(0.584314,0.223529,0.898039)
amove 6.2 4.4
begin rotate 5
 text \tex{Ba$_2$NaOsO$_6$}
end rotate




!!! small inset of pulsed field data !!!

set color black

!xgraphsizesmall = 2
ygraphsizesmall = 2.3

ygraphpos=0.2

amove xgraphpos+xgraphsize/2 ygraphpos+0.05
set just tc
text \tex{$B$ (T)}

amove xgraphpos ygraphpos-0.05
begin graph
 size xgraphsize ygraphsize
 nobox
 !xtitle "\tex{$B$ (T)}" dist 0
 xaxis min 0 max 45 dticks 10
 xaxis format "round 1 prepend \tex{$ append $}"
 xticks off
 xsubticks off
 xside off
 yaxis off
end graph

amove xgraphpos ygraphpos
begin graph
 nobox
 size xgraphsize ygraphsizesmall
 !xtitle "\tex{$B$ (T)}"
 ytitle "\tex{$M$ ($\mu _{\mathrm{B}}$/f.u.)}"
 xaxis min 0 max 45 dticks 10 dsubticks 5
 xticks length tt
 xlabels off
 yaxis min 0 max 0.25 dticks 0.1 dsubticks 0.05
 yaxis format "round 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt

 data b25t4p5.dat d3=c1,c2 ! Li 25 T M(B) @ 4.5 K
 data b45t4p3.dat d1=c1,c2 ! Li 45 T M(B) @ 4.3 K
 let d3=d3*pulsedtomuB_25T
 let d1=d1*pulsedtomuB_45T
 
 d1 color rgb(0.196078431,0,0.376470588) lstyle 2
 d3 color rgb(0.196078431,0,0.376470588) lstyle 1

 ! to compare scaling of pulsed to SQUID, uncomment this
 !data Ba2LiOsO6-SQUIDDY.dat d7=c1,c2 ! Li M(B)
 !let d7=d7*emutomuBfuLi
 !d7 color red lstyle 3
end graph

begin key
 nobox
 position tl
 text "\tex{(c)}"
end key

set color rgb(0.196078431,0,0.376470588)

begin key
 nobox
 position br
 offset 0 0.08
 text "\tex{Ba$_2$LiOsO$_6$}"
end key