xsize=10
ysize=6
size xsize ysize
pt=0.0352777778 ! 1 postscript point

fs=12*pt  !font size
tt=4*pt   !tick length
lw=0.5*pt !line width
glw=2*lw  !graph line width
ms=4*pt   !marker size

pi=3.1415926535897932

set lwidth lw
set hei fs
set just tl
glw=2*lw

! funky LaTeX commands
begin texpreamble
    % set fonts used for text and maths to Palatino
    \usepackage{mathpazo}
    \renewcommand{\familydefault}{ppl}
    \usepackage{upgreek}
    \usepackage[load=abbr]{siunitx}
end texpreamble

! graph settings
xmn=0
xmx=0.8
xticks=0.2
xsubticks=0.1
ymn=0
ymx=10
yticks=5
ysubticks=1

amove 0 0
begin graph
 size xsize ysize
 nobox
 scale auto
 xtitle "\tex{$\mu$ ($\mu _{\mathrm{B}}$)}"
 ytitle "\tex{$g(\mu )$ ($\mu_{\mathrm{B}}^{-1}$)}"
 xaxis min xmn max xmx dticks xticks dsubticks xsubticks
 xaxis format "round 1 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 xticks length tt
 yaxis min ymn max ymx dticks yticks dsubticks ysubticks
 yaxis format "fix 0 prepend \tex{$ append $}" ! makes axis labels TeX. Must give format first.
 yticks length tt
 data Ba2LiOsO6-muOs-pdfs.tsv d1=c1,c2
 data Ba2LiOsO6-muOs-pdfs.tsv d2=c1,c5
 data Ba2LiOsO6-muOs-pdfs.tsv d3=c1,c7
 d1 deresolve 2 average color rgb(1,0.05098,0.05098) lstyle 1 lwidth glw
 d3 color rgb(0.372549,0.619608,0.803922) lstyle 3 lwidth glw
 d2 deresolve 2 average color rgb(0.082353,0.258824,0.388235) lstyle 5 lwidth glw
end graph

begin key
 nobox
 position tr
 llen 0.78
 text "\tex{~~~FM $[1\,1\,1]$}"
 text "\tex{AFM $[1\,1\,1]$}"
 text "\tex{AFM $[0\,0\,1]$}"
 separator
 color rgb(1,0.05098,0.05098) lstyle 1 lwidth glw
 color rgb(0.082353,0.258824,0.388235) lstyle 5 lwidth glw
 color rgb(0.372549,0.619608,0.803922) lstyle 3 lwidth glw
end key